ДиспетчерПровайдеровИИ_зи

Модуль даёт прямой доступ к возможностям сервиса провайдера. Для запроса к модели удобнее ВыполнитьЗапросПоПромту: он сам собирает сообщения из промта, подбирает под модель режим схемы ответа и уровень рассуждений, проверяет ответ. Диспетчер нужен, когда:

• требуется другая возможность сервиса — вопросы к модели решений, эмбеддинги, изображения, речь, видео;

• операция состоит из нескольких обращений, и нужны их общий расход и общая операция в журнале запросов.

Где вызывать и что такое единый результат — в разделе Программный интерфейс.

Возможности

Возможность задаётся строкой — точным именем из таблицы.

Неподдерживаемая возможность отклоняется до обращения к сети с кодом 400. Проверить заранее можно функцией ВозможностьПоддерживается.

Если модель из параметров есть в справочнике моделей провайдера, диспетчер сверяет запрос с её каталогом — входом и выходом модели. До обращения к сети с кодом 400 отклоняются:

• файл, которого модель не принимает, — например, изображение для модели, которая по каталогу читает только текст;

• ЧатЗавершения с моделью решений и Решения с моделью, у которой нет выхода «решения».

Если модели нет в справочнике или вход и выход у неё в каталоге не указаны, запрос уходит без этой проверки.

ВыполнитьВозможность

Выполняет одно обращение к сервису провайдера.

Функция ВыполнитьВозможность(Провайдер, Возможность, Параметры = Неопределено,
	Сессия = Неопределено) Экспорт

Возвращаемое значение. Единый результат, дополненный полем Сведения (см. ниже).

Исключение. Непредвиденный сбой во время обращения записывается в журнал запросов с кодом 500, после чего исключение передаётся вызывающему.

Параметры возможностей

Обязательные ключи выделены жирным. Пропущенный обязательный ключ — отказ 400 с перечнем недостающих.

Для всех возможностей необязателен Таймаут (Число) — сколько секунд ждать ответа, по умолчанию 180. Ноль или не число — отказ 400.

Модель — Строка, идентификатор модели в том виде, в каком он записан в справочнике моделей. К формату сервиса коннектор приводит его сам; полный идентификатор сервиса (содержит ://) уходит как есть.

ЧатЗавершения

Данные — Соответствие с ответом сервиса в формате OpenAI-совместимого API (choices, usage). Текст ответа проще взять из Сведения.Ответ.

Решения

Модель решений не пишет текст: она оценивает то, что ей показали (состояние), и отвечает на заданные вопросы с вероятностями. Такие модели в справочнике моделей отмечены выходом «решения», например openai/gpt-6-luna-decisions. Вызывать их через ЧатЗавершения нельзя, а через ВыполнитьЗапросПоПромту — можно: промт с моделью решений сам уходит этой возможностью.

Температура, лимит токенов, уровень рассуждений, схема ответа и дополнительные параметры у этой возможности не передаются.

Вопрос:

Инструкция (Строка) обязательна — что именно оценить.

Ограничения сервиса проверяются до обращения к сети, отказ — код 400 с причиной: неизвестный тип вопроса, пустая инструкция, число вариантов или уровней вне пределов, нет ни состояния, ни файлов, неподходящий тип или число файлов, тело запроса больше 4 500 000 байт. Изображения уходят в тело в Base64 — это примерно на треть больше их размера, поэтому в сумме они должны занимать не больше 3,3 МБ.

Данные — Соответствие с ответом сервиса как есть. Удобнее брать ответы из Сведения.Решения.

Сведения.Решения — Соответствие: ключ — имя вопроса, значение — Структура:

Сервис сообщает токены запроса и ответа. Стоимость он сообщает отдельно, и коннектор запрашивает её сам — см. расход.

Вопрос = Новый Структура;
Вопрос.Вставить("Тип", "Выбор");
Вопрос.Вставить("Инструкция", "Что на снимке: документ на листе, кассовая лента или не документ?");
Вопрос.Вставить("Критерии", СтрРазделить("sheet,tape,other", ","));

Вопросы = Новый Соответствие;
Вопросы.Вставить("kind", Вопрос);

Файлы = Новый Массив;
Файлы.Добавить(Новый Структура("ИмяФайла, ДанныеФайла", "scan.jpg", ДанныеСнимка));

Параметры = Новый Структура;
Параметры.Вставить("Модель", "openai/gpt-6-luna-decisions");
Параметры.Вставить("Вопросы", Вопросы);
Параметры.Вставить("Файлы", Файлы);

Результат = ДиспетчерПровайдеровИИ_зи.ВыполнитьВозможность(Провайдер, "Решения", Параметры);
Если Результат.Успешно Тогда
	Ответ = Результат.Сведения.Решения.Получить("kind");
	ВидНосителя = Ответ.Значение;      // "tape"
	Уверенность = Ответ.Уверенность;   // 0.97
КонецЕсли;

Остальные возможности

Состав ответов видео-возможностей определяет сервис — сверяйтесь с документацией RouterAI.

Сведения

Сведения — Структура с подробностями обращения. Есть в результате всегда, кроме отказа из-за транзакции.

Остальные поля описывают отправленный запрос — модель, температуру, таймаут, тексты — и повторяют то, что показывает журнал запросов.

Пример

Функция ВекторыТекстов(Провайдер, Тексты)

	Параметры = Новый Структура;
	Параметры.Вставить("Модель", "openai/text-embedding-3-small"); // как в справочнике моделей
	Параметры.Вставить("ВходныеДанные", Тексты);

	Результат = ДиспетчерПровайдеровИИ_зи.ВыполнитьВозможность(Провайдер, "Эмбеддинги", Параметры);
	Если НЕ Результат.Успешно Тогда
		ВызватьИсключение Результат.ОписаниеОшибки;
	КонецЕсли;

	Векторы = Новый Массив;
	Для Каждого Элемент Из Результат.Данные.Получить("data") Цикл
		Векторы.Добавить(Элемент.Получить("embedding"));
	КонецЦикла;

	Возврат Векторы;

КонецФункции

НоваяСессия

Создаёт сессию — операцию из нескольких обращений. Обращения одной сессии объединяются в журнале запросов идентификатором операции, а их расход накапливается в сессии.

Функция НоваяСессия(Провайдер, Промт = Неопределено, Модель = Неопределено) Экспорт

Возвращаемое значение. Структура. Вам может пригодиться поле ИдентификаторОперации (УникальныйИдентификатор) — отбор обращений операции в журнале. Остальные поля служебные: не меняйте их и не собирайте сессию сами. Сессия привязана к провайдеру — для другого провайдера создайте свою.

Сессия = ДиспетчерПровайдеровИИ_зи.НоваяСессия(Провайдер);
Для Каждого Порция Из ПорцииТекстов Цикл
	Параметры = Новый Структура("Модель, ВходныеДанные", ИдентификаторМодели, Порция);
	Результат = ДиспетчерПровайдеровИИ_зи.ВыполнитьВозможность(Провайдер, "Эмбеддинги",
		Параметры, Сессия);
	Если НЕ Результат.Успешно Тогда
		Прервать;
	КонецЕсли;
	// Обработка векторов порции.
КонецЦикла;
Расход = ДиспетчерПровайдеровИИ_зи.ЗавершитьОперацию(Сессия, Результат);

ЗавершитьОперацию

Закрывает операцию сессии и возвращает её расход.

Функция ЗавершитьОперацию(Сессия, Результат) Экспорт

Возвращаемое значение. Структура — расход всех обращений сессии (копия).

Если Результат.Успешно = Ложь, а последнее обращение к сервису прошло успешно (операция не удалась по вашей причине — например, ответ не прошёл вашу проверку), ОписаниеОшибки дописывается к последней записи операции в журнале. Вызывать метод не обязательно, но без него не будет ни общего расхода, ни этой отметки.

ВозможностьПоддерживается

Проверяет без обращения к сети, поддерживает ли провайдер возможность, — например, чтобы скрыть команду, которую сервис не выполнит.

Функция ВозможностьПоддерживается(Провайдер, Возможность) Экспорт

Параметры. Провайдер — СправочникСсылка.ПровайдерыИИ_зи; Возможность — Строка.

Возвращаемое значение. Булево. Ложь — и для провайдера, которого нет или у которого не задан вид. Признак «Используется» и настройки подключения не проверяются.